ПЦУСБ/Лекция 6 — различия между версиями

library ieee;
use ieee.std_logic_1164.all;
use work.block1_pkg.all;
 
 
use work.block1_pkg. all;
 
entity block1_model is
 
  port (
    PortsInRec    : In PortsInRecType;
    PortsOutRec   : out PortsOutRecType;
 
    SetPassword : out  std_logic;
    DigitalKey  : out  std_logic_vector(9 downto 0);
    Esc         : out  std_logic;
    clk         : out  std_logic;        -- синхросигнал 25 МГц
    rst         : out  std_logic;
    LedOpen     : in  std_logic;
    Speaker     : in std_logic
    );
 
end entity block1_model;
 
architecture beh of block1_model is
 
begin  -- architecture beh
 
  SetPassword <= PortsInRec.SetPassword;
  DigitalKey  <= PortsInRec.DigitalKey;
  Esc         <= PortsInRec.Esc;
  clk         <= PortsInRec.clk;
  rst         <= PortsInRec.rst;
  PortsOutRec.LedOpen <= LedOpen;
  PortsOutRec.Speaker <= Speaker;
 
end architecture beh;

library ieee;
use ieee.std_logic_1164.all;
 
package block1_pkg is
 
 
--  subtype String100 is string(1 to 100);
--  FUNCTION resolved ( s : resolved_character ) RETURN character;
--  subtype TString is resolved String100;
  subtype TString is string(1 to 100);
 
  type PortsInRecType is record
    SetPassword : std_logic;
    DigitalKey  : std_logic_vector(9 downto 0);
    Esc         : std_logic;
    clk         : std_logic;
    rst         : std_logic;
--    LedOpen     : std_logic;
--    Speaker     : std_logic;
    Info        : TString;
  end record PortsInRecType;
 
  type PortsOutRecType is record
    LedOpen     : std_logic;
    Speaker     : std_logic;
  end record PortsOutRecType;
 
 
  type KeyType is (D0, D1, D2, D3, D4, D5, D6, D7, D8, D9,
               Esc, rst, clk, SetPass, SetPassword, Pass, clean);
 
  type time_vec is array (1 to 3) of time;
 
  procedure Init ( signal PortsRec : out PortsInRecType);
  procedure SetSignal  (
    signal PortsRec   : out PortsInRecType;
    SignalName : in  KeyType;
    value      :     std_logic);
  procedure PressKey (
    signal PortsRec : out PortsInRecType;
    KeyCode         : in  KeyType;
    PressDelay      : in  time := 50 ns;
    WaitAfterPress  : in  time := 50 ns
    );
  procedure EnterPass (
    signal PortsInRec : out PortsInRecType;
    signal PortsOutRec : in PortsOutRecType;
    Pass            : in  string(1 to 3) := "000";
    PressDelay      : in  time_vec := (others => 50 ns);
    WaitAfterPress  : in  time_vec := (others => 50 ns)
    );
 
end package block1_pkg;
 
package body block1_pkg is
 
  procedure Init (
    signal PortsRec : out PortsInRecType) is
  begin  -- procedure Init
    PortsRec.SetPassword <= '0';
    PortsRec.DigitalKey <= (others => '0');
    PortsRec.Esc        <= '0';
    PortsRec.rst        <= '1';
    PortsRec.clk        <= 'Z';
--    PortsRec.LedOpen    <= 'Z';
--    PortsRec.Speaker    <= 'Z';
--    PortsRec.Info       <= (others => ' ');
    wait for 21 ns;
    PortsRec.rst        <= '0';
  end procedure Init;
 
  procedure SetSignal  (
    signal PortsRec   : out PortsInRecType;
    SignalName : in  KeyType;
    value      :     std_logic) is
  begin  -- procedure Init
    case SignalName is
      when D0          => PortsRec.DigitalKey(0) <= value;
      when D1          => PortsRec.DigitalKey(1) <= value;
      when D2          => PortsRec.DigitalKey(2) <= value;
      when D3          => PortsRec.DigitalKey(3) <= value;
      when D4          => PortsRec.DigitalKey(4) <= value;
      when D5          => PortsRec.DigitalKey(5) <= value;
      when D6          => PortsRec.DigitalKey(6) <= value;
      when D7          => PortsRec.DigitalKey(7) <= value;
      when D8          => PortsRec.DigitalKey(8) <= value;
      when D9          => PortsRec.DigitalKey(9) <= value;
      when Esc         => PortsRec.Esc           <= value;
      when rst         => PortsRec.rst           <= value;
--      when clk         => PortsRec.clk           <= value;
      when SetPass|SetPassword|Pass
                         => PortsRec.SetPassword   <= value;
      when clean       =>
                            PortsRec.SetPassword  <= '0';
                            PortsRec.DigitalKey   <= (others => '0');
                            PortsRec.Esc          <= '0';
                            PortsRec.rst          <= '0';
      when others      => null;
    end case;
  end procedure SetSignal;
 
 
  procedure PressKey (
    signal PortsRec : out PortsInRecType;
    KeyCode         : in  KeyType;
    PressDelay      : in  time := 50 ns;
    WaitAfterPress  : in  time := 50 ns
    ) is
  begin  -- procedure Init
 
    SetSignal(PortsRec, KeyCode, '1');
    wait for PressDelay ;
    SetSignal(PortsRec, KeyCode, '0');
    wait for WaitAfterPress ;
  end procedure PressKey;
 
  function CharToKeyCode (KeyCodeChar : character) return KeyType is
    variable KeyCode : KeyType := D0;
  begin
 
    case KeyCodeChar is
      when '0' => KeyCode := D0;
      when '1' => KeyCode := D1;
      when '2' => KeyCode := D2;
      when '3' => KeyCode := D3;
      when '4' => KeyCode := D4;
      when '5' => KeyCode := D5;
      when '6' => KeyCode := D6;
      when '7' => KeyCode := D7;
      when '8' => KeyCode := D8;
      when '9' => KeyCode := D9;
      when 'E'|'e' => KeyCode := Esc;
      when 'S'|'s' => KeyCode := SetPassword;
      when others => null;
    end case;
    return KeyCode;
 
  end function CharToKeyCode;
 
  procedure EnterPass (
    signal PortsInRec : out PortsInRecType;
    signal PortsOutRec : in PortsOutRecType;
    Pass            : in  string(1 to 3) := "000";
    PressDelay      : in  time_vec := (others => 50 ns);
    WaitAfterPress  : in  time_vec := (others => 50 ns)
    ) is
    variable KeyCode : KeyType;
  begin  -- procedure Init
--    PortsRec.DigitalKey <= (others => 'Z');
    for i in 1 to 3 loop
      KeyCode := CharToKeyCode(Pass(i));
      --PortsInRec.Info <= ( & Pass & " " , others => ' ');
      PortsInRec.Info <= (Pass & " -  ("& pass(i) & ")", others => ' ' );
 
      PressKey(PortsInRec, KeyCode, PressDelay(i), WaitAfterPress(i));
 
    end loop;  -- i
    -- ожидание перехода в start
    PortsInRec.Info <= ("wait Start", others => ' ' );
    wait
      until (PortsOutRec.LedOpen = '0' and PortsOutRec.LedOpen'event)
      or (PortsOutRec.Speaker = '0' and PortsOutRec.Speaker'event)
      for 100000 ns;
 
  end procedure EnterPass;
 
end package body block1_pkg;

library ieee;
use ieee.std_logic_1164.all;
use work.block1_pkg.all;
 
entity block1_TestCtrl is
 
  port (
    PortsInRec    : out PortsInRecType;
    PortsOutRec   : in  PortsOutRecType
    );
 
end entity block1_TestCtrl;
 
architecture Test1 of block1_TestCtrl is
 
  signal Clk : std_logic := '1';
 
 
begin  -- architecture Test1
 
 
  -- clock generation
  Clk <= not Clk after 5 ns;
  PortsInRec.clk <= clk;
 
  -- waveform generation
  WaveGen_Proc: process
  begin
    -- insert signal assignments here
 
    Init(PortsInRec);
    --wait for 50 ns;
 
    EnterPass(PortsInRec, PortsOutRec, "123");
    EnterPass(PortsInRec, PortsOutRec, "000");
    EnterPass(PortsInRec, PortsOutRec, "1ee");
    EnterPass(PortsInRec, PortsOutRec, "12e");
    EnterPass(PortsInRec, PortsOutRec, "123", (others => 100 ns), (others => 100000 ns));
    wait for 1000 ns;
 
    assert false report "END Simulation" severity failure;
    wait;
  end process WaveGen_Proc;
 
end architecture Test1;